清空桌面图标缓存

bat

rem 关闭Windows外壳程序explorer

taskkill /f /im explorer.exe

rem 清理系统图标缓存数据库

attrib -h -s -r "%userprofile%\AppData\Local\IconCache.db"

del /f "%userprofile%\AppData\Local\IconCache.db"

attrib /s /d -h -s -r "%userprofile%\AppData\Local\Microsoft\Windows\Explorer\*"

del /f "%userprofile%\AppData\Local\Microsoft\Windows\Explorer\thumbcache_32.db"
del /f "%userprofile%\AppData\Local\Microsoft\Windows\Explorer\thumbcache_96.db"
del /f "%userprofile%\AppData\Local\Microsoft\Windows\Explorer\thumbcache_102.db"
del /f "%userprofile%\AppData\Local\Microsoft\Windows\Explorer\thumbcache_256.db"
del /f "%userprofile%\AppData\Local\Microsoft\Windows\Explorer\thumbcache_1024.db"
del /f "%userprofile%\AppData\Local\Microsoft\Windows\Explorer\thumbcache_idx.db"
del /f "%userprofile%\AppData\Local\Microsoft\Windows\Explorer\thumbcache_sr.db"

rem 清理 系统托盘记忆的图标

echo y|reg delete "HKEY_CLASSES_ROOT\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify" /v IconStreams
echo y|reg delete "HKEY_CLASSES_ROOT\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify" /v PastIconsStream

rem 重启Windows外壳程序explorer

start explorer

打印机卡死解决

bat

@echo off
REM 检查是否以管理员身份运行
net session >nul 2>&1
if %errorlevel% neq 0 (
    echo 错误：请以管理员身份运行此脚本！
    echo 1. 右键点击此文件
    echo 2. 选择"以管理员身份运行"
    pause
    exit /b
)

REM 停止打印服务
echo 正在停止打印服务...
net stop spooler >nul 2>&1

REM 清空打印队列
echo 正在清空打印队列...
del /Q /F "C:\Windows\System32\spool\PRINTERS\*" >nul 2>&1

REM 重启打印服务
echo 正在重启打印服务...
net start spooler >nul 2>&1

echo.
echo 操作完成！打印队列已清空
echo 1. 打印服务已停止
echo 2. 打印队列已清空
echo 3. 打印服务已重启
echo.
pause

格式化D盘并重启

bat

@echo off
:: 执行格式化命令并捕获返回值
format D: /X /Q /FS:NTFS /V:Data1 /Y

:: 检查上一条命令的返回值（errorlevel）
if errorlevel 1 (
    echo 格式化失败，返回值: %errorlevel%
    exit /b 1
) else (
    echo 格式化成功，返回值: %errorlevel%
    :: 执行重启命令（立即重启，不延迟）
    shutdown -r -t 0
    echo 系统将在0秒后重启...
)

恢复 Windows 10 LTSC 默认照片查看器

bat

@echo off&cd\&color 0a&cls
echo 恢复Windows 照片查看器
reg add "HKLM\SOFTWARE\Microsoft\Windows Photo Viewer\Capabilities\FileAssociations" /v ".jpg" /t REG_SZ /d PhotoViewer.FileAssoc.Tiff /f
reg add "HKLM\SOFTWARE\Microsoft\Windows Photo Viewer\Capabilities\FileAssociations" /v ".jpeg" /t REG_SZ /d PhotoViewer.FileAssoc.Tiff /f
reg add "HKLM\SOFTWARE\Microsoft\Windows Photo Viewer\Capabilities\FileAssociations" /v ".bmp" /t REG_SZ /d PhotoViewer.FileAssoc.Tiff /f
reg add "HKLM\SOFTWARE\Microsoft\Windows Photo Viewer\Capabilities\FileAssociations" /v ".png" /t REG_SZ /d PhotoViewer.FileAssoc.Tiff /f
echo 请双击或右击图片，选择“照片查看器”即可
pause